Почему Конта нельзя сделать примером Монадера?


У меня есть стек трансформаторов монад, включающий ErrorT, и я хочу обернуть трансформатор ContT r вокруг всего этого. Когда я пытаюсь это сделать, мои вызовы throwError генерируют ошибки типа - очевидно, ContT r не является автоматически экземпляром MonadError. Отлично, подумал я , я просто превращу его в один:

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError = liftCatch . catchError

Используя некоторое подходящее определение liftCatch. Но теперь я получаю ошибки при компиляции:

srcLanguageTypes.hs:68:10:
    Illegal instance declaration for `MonadError e (ContT r m)'
      (the Coverage Condition fails for one of the functional dependencies;
       Use -XUndecidableInstances to permit this)
    In the instance declaration for `MonadError e (ContT r m)'

Я с удовольствием использую прагму UndecidableInstances (у меня сложилось впечатление, что это не так слишком тревожно, например, см. этот вопрос ), но я задался вопросом, есть ли трудности в создании трансформатора продолжения в экземпляр MonadError - я думаю, что если бы это было нормально, авторы пакета Control.Monad.Trans уже сделали бы это... так ведь?

1 5

1 ответ:

ContT и ErrorT допускают нестандартный поток управления. Есть способ, чтобы обернуть типа ErrorT вокруг смотрит в МТЛ:

instance (Error e, MonadCont m) => MonadCont (ErrorT e m)
Но эти два трансформатора монад не коммутируют. Запоминание:
newtype Identity a = Identity {runIdentity :: a}
newtype ErrorT e m a = ErrorT {runErrorT :: m (Either e a)}
newtype ContT r m a = ContT {runContT :: (a -> m r) -> m r}

ErrorT String (ContT Bool Identity) () что нормально в пакете mtl может быть:

ErrorT (ContT ( \ (k :: Either String () -> Identity Bool) -> k (Right ()) ) )

ContT r (ErrorT e Identity) a не в порядке в пакете mtl. Но вы можете написать его.

Какую семантику ( > > = ) вы хотите видеть в комбинированной монаде? Как вы ожидаете, что ваш стек вложенных обработчиков ошибок будет взаимодействовать с нелокальными позвонить в полицию?

Вот как я мог бы это написать:

{-# LANGUAGE FlexibleInstances, MultiParamTypeClasses, UndecidableInstances   #-}
import Control.Monad
import Control.Monad.Cont
import Control.Monad.Error
import Data.Function
import Data.IORef

handleError :: MonadError e m => (e -> m a) -> m a -> m a
handleError = flip catchError

test2 :: ErrorT String (ContT () IO) ()
test2 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go2 = runContT (runErrorT test2) (either error return)

{-

*Main> go2
1
2
3
4
*** Exception: ouch:middle:top

-}

Итак, вышеизложенное работает только с mtl, вот новый экземпляр и как он работает:

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError op h = ContT $ \k -> catchError (runContT op k) (\e -> runContT (h e) k)

test3 :: ContT () (ErrorT String IO) ()
test3 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go3 = runErrorT (runContT test3 return)

{-

*Main> go3
1
2
3
4
Left "ouch:middle:3:middle:2:middle:1:middle:top"

-}