я беру небольшую проблему с одобренным ответом на изоморфизм, поскольку определение теории категорий изоморфизма ничего не говорит об объектах. Чтобы понять почему, давайте рассмотрим определение.

определение

изоморфизм-это пара морфизмов (т. е. функции), f и g, таких, что:

f . g = id
g . f = id

эти морфизмы затем называются"iso" морфизмы. Многие люди не понимают, что "морфизм" в изоморфизме относится к функции и не объект. Однако вы бы сказали, что объекты, которые они соединяют, "изоморфны", что и описывает другой ответ.

обратите внимание, что определение изоморфизма не сказать, что (.),id или = должно быть. Единственное требование состоит в том, что, каковы бы они ни были, они также удовлетворяют законам категории:

f . id = f
id . f = f
(f . g) . h = f . (g . h)

состав (т. е. (.)) соединяет два морфизма в один морфизм и id обозначает своего рода " идентичность" переход. Это означает, что если наши изоморфизмы сводятся к морфизму тождества id, тогда вы можете думать о них как инверсиями друг друга.

для конкретного случая, когда морфизмы являются функциями, то id определяется как функция личности:

id x = x

... а состав определяется как:

(f . g) x = f (g x)

... и две функции являются изоморфизмами, если они отменяют функцию идентичности id когда вы сочиняете их.

морфизмы против объектов

однако есть несколько способов, которыми два объекта могут быть изоморфными. Например, учитывая следующие два типа:

data T1 = A | B
data T2 = C | D

между ними есть два изоморфизма:

f1 t1 = case t1 of
    A -> C
    B -> D
g1 t2 = case t2 of
    C -> A
    D -> B

(f1 . g1) t2 = case t2 of
    C -> C
    D -> D
(f1 . g1) t2 = t2
f1 . g1 = id :: T2 -> T2

(g1 . f1) t1 = case t1 of
    A -> A
    B -> B
(g1 . f1) t1 = t1
g1 . f1 = id :: T1 -> T1

f2 t1 = case t1 of
    A -> D
    B -> C
g2 t2 = case t2 of
    C -> B
    D -> A

f2 . g2 = id :: T2 -> T2
g2 . f2 = id :: T1 -> T1

вот почему лучше описать изоморфизм в терминах конкретных функций, связанных с двумя объектами, а не с двумя объектами, поскольку между двумя объектами не обязательно может быть уникальная пара функций объекты, удовлетворяющие законам изоморфизма.

кроме того, обратите внимание, что недостаточно, чтобы функции были обратимы. Например, следующие пары функций не являются изоморфизмами:

f1 . g2 :: T2 -> T2
f2 . g1 :: T2 -> T2

даже если никакая информация не теряется, когда вы составляете f1 . g2, вы не вернетесь в исходное состояние, даже если конечное состояние имеет тот же тип.

кроме того, изоморфизмы не должны быть между конкретными типами данных. Вот пример из двух канонические изоморфизмы не находятся между конкретными алгебраическими типами данных и вместо этого просто связывают функции:curry и uncurry:

curry . uncurry = id :: (a -> b -> c) -> (a -> b -> c)
uncurry . curry = id :: ((a, b) -> c) -> ((a, b) -> c)

использует для Изоморфизмы

Церковь Кодирование

один из вариантов использования изоморфизм является церковь-кодировать типы данных, функции. Например, Bool изоморфна forall a . a -> a -> a:

f :: Bool -> (forall a . a -> a -> a)
f True  = \a b -> a
f False = \a b -> b

g :: (forall a . a -> a -> a) -> Bool
g b = b True False

убедитесь в том, что f . g = id и g . f = id.

преимущество типов данных церковного кодирования заключается в том, что они иногда они работают быстрее (потому что церковное кодирование-это стиль продолжения), и они могут быть реализованы на языках, которые даже не имеют языковой поддержки для алгебраических типов данных вообще.

Перевод Реализаций

иногда пытаются сравнить реализацию одной библиотеки какой-либо функции с реализацией другой библиотеки, и если вы можете доказать, что они изоморфны, то вы можете доказать, что они одинаково сильны. Кроме того, изоморфизмы описывают как перевести одну библиотеку в другую.

например, существует два подхода, которые обеспечивают возможность определения монады из сигнатуры функтора. Один из них-свободная монада, предоставленная free пакет и другая операционная семантика, предоставленная operational пакета.

если вы посмотрите на два основных типа данных, они выглядят по-разному, особенно их вторые конструкторы:

-- modified from the original to not be a monad transformer
data Program instr a where
    Lift   :: a -> Program instr a
    Bind   :: Program instr b -> (b -> Program instr a) -> Program instr a
    Instr  :: instr a -> Program instr a

data Free f r = Pure r | Free (f (Free f r))

... но на самом деле они изоморфны! Что означает, что оба подхода являются одинаково мощными, и любой код, написанный в одном подходе, может быть механически переведен в другой подход с использованием изоморфизмов.

Изоморфизмы, которые не являются функциями

кроме того, изоморфизмы не ограничивается функциями. Они фактически определены для любого Category и Haskell имеет множество категорий. Вот почему более полезно думать в терминах морфизмов, а не типов данных.

например,Lens тип (от data-lens) формирует категорию, в которой вы можете создавать линзы и иметь идентификационный объектив. Поэтому, используя наш приведенный выше тип данных, мы можем определить две линзы, которые являются изоморфизмами:

lens1 = iso f1 g1 :: Lens T1 T2
lens2 = iso g1 f1 :: Lens T2 T1

lens1 . lens2 = id :: Lens T1 T1
lens2 . lens1 = id :: Lens T2 T2

обратите внимание, что в игре есть два изоморфизма. Один из них-изоморфизм, который используется для построения каждой линзы (т. е. f1 и g1) (и именно поэтому эта строительная функция называется iso), и тогда сами линзы также являются изоморфизмами. Отметим, что в приведенной выше формулировке, композиция (.) используется не функциональная композиция, а скорее композиция объектива, и id не является функцией идентификации, но вместо этого является объективом идентификации:

id = iso id id

это означает, что если мы составим наши две линзы, результат должен быть неотличим от этой линзы идентичности.