Заводные именованные параметры вызывают назначение параметров для переключения-есть ли способ обойти это?

Groovy соберет все именованные параметры в карту и передаст ее в метод в качестве первого параметра. Это кажется аккуратным,но после попытки заставить его работать он кажется действительно непригодным.

Таким образом, проблема заключается в следующем методе: 

def method(paramMap, specificVar1 = 7, specificVar2 = 14)

Когда вы вызываете этот метод с чем-то вроде этого: 

method(12, extraValue: "hello")

Вы получаете в значительной степени то, что ожидаете: 

assert 12 == specificVar1
assert 14 == specificVar2
assert [extraValue:"hello"] == paramMap

Неплохо, имеет смысл. Проблема в том, что если вы предполагаете, что парамы Map необязательны, то вы можете в конечном итоге получить значения, подобные этому: 

method(12)

assert paramMap == 12
assert specificVar1 == 7 // default values
assert specificVar2 == 14

Этот скаляр должен был войти в specificVar, а не в карту. Если я специально наберу карту в методе: 

def method(Map paramMap, specificVar1 = 7, specificVar2 = 14)

Тогда method(12, extraValue: "hello") работает так же, как и раньше, но method(12) бросает ClassCastException. Это просто не кажется полезным. Есть ли способ сделать это Map "липким", чтобы оно просто было пустым, если нет параметров Map?

1 5
groovy named-parameters

1 ответ:

Установка значений по умолчанию для параметров создает перегруженные методы с комбинациями, выполненными слева направо, таким образом, трудно сделать method(12), а также иметь возможность передавать записи карты.

Ваш метод def method(paramMap, specificVar1=7, specificVar2=14) будет генерировать следующие методы: 

Object Maps.method(java.lang.Object)
Object Maps.method(java.lang.Object,java.lang.Object)
Object Maps.method(java.lang.Object,java.lang.Object,java.lang.Object)

И полностью типизированный метод с картой param: 

def method3(Map paramMap=[:], Integer specificVar1=7, Integer specificVar2=14) {
}

Будет генерировать следующие методы: 

Object Maps.method3()
Object Maps.method3(java.util.Map)
Object Maps.method3(java.util.Map,java.lang.Integer)
Object Maps.method3(java.util.Map,java.lang.Integer,java.lang.Integer)

(нет подходящего метода для method(12)).

Кроме того, записи, переданные методу, будут собраны и вставляется в первый параметрmap . Следующий метод: 

def method4(Integer specificVar1=7, Integer specificVar2=14, Map map=[:]) {

Генерирует: 

Object Maps.method4()
Object Maps.method4(java.lang.Integer)
Object Maps.method4(java.lang.Integer,java.lang.Integer)
Object Maps.method4(java.lang.Integer,java.lang.Integer,java.util.Map)

Таким образом, method4 12, a:'b' терпит неудачу с: 

No signature of method: Maps.method4() is applicable for argument types: 
  (java.util.LinkedHashMap, java.lang.Integer) values: [[a:b], 12]
Так что, нет, я не думаю, что вы можете делать то, что вы хотите, используя карты :-).

Решение 1:

Если вы ищете чисто динамическое решение, вы можете использовать один аргумент карты: 

def method5(Map map) {
  def specificVar1 = map.specificVar1 ?: 7
  def specificVar2 = map.specificVar2 ?: 14
}

Решение 2 (обновлено):

Можно создать класс для представления параметров. Использование карты принуждение к объекту является статически компилируемым и синтаксическим сахаром для него.

@groovy.transform.CompileStatic
class Maps {
  def method6(Foo foo) { "$foo.params, $foo.specificVar1, $foo.specificVar2" }
  def method6(Map map) { method6 map as Foo }

  static main(args) {
    def maps = new Maps()

    assert maps.method6(params: [a: 'b', c: 'd'], specificVar1: 40) ==
        "[a:b, c:d], 40, 14"

    assert maps.method6(new Foo(params: [a: 'b', c: 'd'], specificVar2: 21)) == 
        "[a:b, c:d], 7, 21"
  }
}

class Foo {
  def specificVar1 = 7, specificVar2 = 14, params = [:]
}

Решение 3:

Перегруженный метод.

def method6(Map paramMap, Integer specificVar1=7, Integer specificVar2=14) {
  "$paramMap, $specificVar1, $specificVar2"
}

def method6(Integer specificVar1=7, Integer specificVar2=14) {
  method6 [:], specificVar1, specificVar2
}


assert method6( 12 ) == "[:], 12, 14"
assert method6( ) == "[:], 7, 14"
assert method6( a:'b', 18 ) == "[a:b], 18, 14"
assert method6( 18, a:'b', 27 ) == "[a:b], 18, 27"
assert method6( 90, 100 ) == "[:], 90, 100"
assert method6( a:'b', 140, c:'d' ) == "[a:b, c:d], 140, 14"

Метод версии карты не может иметь параметр по умолчанию, в противном случае оба метода будут генерировать непараметрический method6, и они будут конфликтовать.

11