Обновление всех сводных таблиц в моей книге excel с помощью макроса


У меня есть книга с 20 различными сводными таблицами. Есть ли простой способ найти все сводные таблицы и обновить их в VBA?

10 71

10 ответов:

да.

ThisWorkbook.RefreshAll

или, если ваша версия Excel достаточно старый,

Dim Sheet as WorkSheet, Pivot as PivotTable
For Each Sheet in ThisWorkbook.WorkSheets
    For Each Pivot in Sheet.PivotTables
        Pivot.RefreshTable
        Pivot.Update
    Next
Next

этот код VBA обновит все сводные таблицы / диаграммы в книге.

Sub RefreshAllPivotTables()

Dim PT As PivotTable
Dim WS As Worksheet

    For Each WS In ThisWorkbook.Worksheets

        For Each PT In WS.PivotTables
          PT.RefreshTable
        Next PT

    Next WS

End Sub

другой непрограммный вариант:

  • щелкните правой кнопкой мыши на каждой сводной таблице
  • выберите параметры таблицы
  • ТИК 'открыть'.
  • нажмите на кнопку OK

это будет обновлять сводную таблицу при каждом открытии книги.

ActiveWorkbook.RefreshAll обновляет все, не только сводные таблицы, но и запросы ODBC. У меня есть несколько запросов VBA, которые ссылаются на подключения к данным, и с помощью этой опции происходит сбой, поскольку команда запускает подключения к данным без подробностей, предоставленных из VBA

Я рекомендую этот вариант, если вы хотите обновить только пивоты

Sub RefreshPivotTables()     
  Dim pivotTable As PivotTable     
  For Each pivotTable In ActiveSheet.PivotTables         
    pivotTable.RefreshTable     
  Next 
End Sub 

в определенных обстоятельствах вы можете различать сводную таблицу и ее PivotCache. Кэш имеет свой собственный метод обновления и свои собственные коллекции. Таким образом, мы могли бы обновить все сводные Кеши вместо сводных таблиц.

разница? Когда вы создаете новую сводную таблицу, вас спрашивают, Хотите ли вы ее использовать на основе предыдущей таблицы. Если вы скажете "нет", эта сводная таблица получит свой собственный кэш и удвоит размер исходных данных. Если вы скажете "Да", вы сохраните свой Книга небольшая, но вы добавляете в коллекцию сводных таблиц, которые совместно используют один кэш. Вся коллекция обновляется при обновлении любой сводной таблицы в этой коллекции. Таким образом, вы можете представить, какая разница может быть между обновлением каждого кэша в книге по сравнению с обновлением каждой сводной таблицы в книге.

в панели инструментов сводной таблицы есть опция обновить все. Этого достаточно. Больше ничего не надо делать.

нажмите ctrl+alt+F5

у вас сводные таблицы коллекция на VB лист "объект". Итак, быстрый цикл, как это будет работать:

Sub RefreshPivotTables()
    Dim pivotTable As PivotTable
    For Each pivotTable In ActiveSheet.PivotTables
        pivotTable.RefreshTable
    Next
End Sub

Записки из окопов:

  1. не забудьте снять защиту с любых защищенных листов перед обновлением сводной таблицы.
  2. сохранить часто.
  3. Я подумаю о большем и обновлю в свое время... :)

удачи!

код

Private Sub Worksheet_Activate()
    Dim PvtTbl As PivotTable
        Cells.EntireColumn.AutoFit
        For Each PvtTbl In Worksheets("Sales Details").PivotTables
        PvtTbl.RefreshTable
        Next
End Sub 

работает нормально.

код используется в модуле активировать лист, поэтому он отображает мерцание / сбой при активации листа.

даже мы можем обновить конкретное соединение и в свою очередь он обновит все шарниры, связанные с ним.

для этого кода я создал срез из таблицы, присутствующей в Excel:

Sub UpdateConnection()
        Dim ServerName As String
        Dim ServerNameRaw As String
        Dim CubeName As String
        Dim CubeNameRaw As String
        Dim ConnectionString As String

        ServerNameRaw = ActiveWorkbook.SlicerCaches("Slicer_ServerName").VisibleSlicerItemsList(1)
        ServerName = Replace(Split(ServerNameRaw, "[")(3), "]", "")

        CubeNameRaw = ActiveWorkbook.SlicerCaches("Slicer_CubeName").VisibleSlicerItemsList(1)
        CubeName = Replace(Split(CubeNameRaw, "[")(3), "]", "")

        If CubeName = "All" Or ServerName = "All" Then
            MsgBox "Please Select One Cube and Server Name", vbOKOnly, "Slicer Info"
        Else
            ConnectionString = GetConnectionString(ServerName, CubeName)
            UpdateAllQueryTableConnections ConnectionString, CubeName
        End If
    End Sub

    Function GetConnectionString(ServerName As String, CubeName As String)
        Dim result As String
        result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
        '"OLEDB;Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False"
        GetConnectionString = result
    End Function

    Function GetConnectionString(ServerName As String, CubeName As String)
    Dim result As String
    result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
    GetConnectionString = result
End Function

Sub UpdateAllQueryTableConnections(ConnectionString As String, CubeName As String)
    Dim cn As WorkbookConnection
    Dim oledbCn As OLEDBConnection
    Dim Count As Integer, i As Integer
    Dim DBName As String
    DBName = "Initial Catalog=" + CubeName

    Count = 0
    For Each cn In ThisWorkbook.Connections
        If cn.Name = "ThisWorkbookDataModel" Then
            Exit For
        End If

        oTmp = Split(cn.OLEDBConnection.Connection, ";")
        For i = 0 To UBound(oTmp) - 1
            If InStr(1, oTmp(i), DBName, vbTextCompare) = 1 Then
                Set oledbCn = cn.OLEDBConnection
                oledbCn.SavePassword = True
                oledbCn.Connection = ConnectionString
                oledbCn.Refresh
                Count = Count + 1
            End If
        Next
    Next

    If Count = 0 Then
         MsgBox "Nothing to update", vbOKOnly, "Update Connection"
    ElseIf Count > 0 Then
        MsgBox "Update & Refresh Connection Successfully", vbOKOnly, "Update Connection"
    End If
End Sub

Я использую команду, указанную ниже, в недавнем прошлом, и она, кажется, работает нормально.

ActiveWorkbook.RefreshAll

надеюсь, что это поможет.

Если вы используете MS Excel 2003, то перейдите в меню Вид - > панель инструментов - > сводная таблица из этой панели инструментов мы можем сделать обновление, нажав кнопку ! этот символ.