Как определить поддержку C++11 компилятора С помощью CMake

на данный момент CMake не имеет удобной формы для поддержки C++11. В идеале, вы должны указать проект C++11 вроде этого:

project(foo CXX11)

в начале CMakeLists.txt. Но это CXX11 тип проекта не существует (пока). До тех пор вы можете использовать двухэтапную технику:

1. Определите тип и версию компилятора
2. отрегулируйте флаги сборки соответственно.

например, это то, что я использую для поддержки C++11 с Clang и GCC:

# Initialize CXXFLAGS.
set(CMAKE_CXX_FLAGS                "-Wall -std=c++11")
set(CMAKE_CXX_FLAGS_DEBUG          "-O0 -g")
set(CMAKE_CXX_FLAGS_MINSIZEREL     "-Os -DNDEBUG")
set(CMAKE_CXX_FLAGS_RELEASE        "-O4 -DNDEBUG")
set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g")

# Compiler-specific C++11 activation.
if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "GNU")
    execute_process(
        COMMAND ${CMAKE_CXX_COMPILER} -dumpversion OUTPUT_VARIABLE GCC_VERSION)
    if (NOT (GCC_VERSION VERSION_GREATER 4.7 OR GCC_VERSION VERSION_EQUAL 4.7))
        message(FATAL_ERROR "${PROJECT_NAME} requires g++ 4.7 or greater.")
    endif ()
elseif ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -stdlib=libc++")
else ()
    message(FATAL_ERROR "Your C++ compiler does not support C++11.")
endif ()

нашел этот сценарий CMake который утверждает, что делает именно то, что вам нужно. Он также может проверить наличие отдельных функций C++11. Я не думаю, что он может решить между std=C++0x и std=C++11 хотя.

на момент написания этой статьи (pre-GCC 4.8), возможно, не стоит обнаруживать флаги C++11 и добавлять их. Это связано с изменением стандарта (по крайней мере, для GCC) нарушает совместимость ABI, что может привести к ошибкам связи.

поэтому использование стандарта C++11 должно быть явно указано с помощью параметра компилятора во время начальная конфигурация CMake проекта, например,

CXX='g++ -std=c++11' cmake /path/to/source

то есть использование-std=c++11 должно рассматриваться как отдельный компилятор, который не должен быть смешан или изменен в проекте.

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
elseif(COMPILER_SUPPORTS_CXX0X)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
else()
    message(FATAL_ERROR "Compiler ${CMAKE_CXX_COMPILER} has no C++11 support.")
endif()

от http://www.guyrutenberg.com/2014/01/05/enabling-c11-c0x-in-cmake/ с незначительными изменениями

в CMake 3.1 * правильный, простой способ сделать это-использовать CXX_STANDARD свойство для заданной цели. Например, учитывая этот простой пример с помощью auto (название main.cpp):

#include <iostream>

int main() {
    auto num = 10;
    std::cout << num << std::endl;
    return 0;
}

следующее CMakeLists.txt включит поддержку C++11:

cmake_minimum_required(VERSION 3.3)
project(Hello CXX)

set(SOURCE_FILES main.cpp)
add_executable(Hello ${SOURCE_FILES})

set_property(TARGET Hello PROPERTY
    CXX_STANDARD 11
    CXX_STANDARD_REQUIRED ON
)

это добавит любые необходимые флаги, такие как -std=c++11. Обратите внимание, что CXX_STANDARD_REQUIRED свойство предотвратит распад стандарта на более раннюю версию.

---

правильный, не такой простой способ чтобы указать CMAKE_CXX_KNOWN_FEATURES что вы используете, например cxx_auto_type:

cmake_minimum_required(VERSION 3.3)
project(Hello CXX)

set(SOURCE_FILES main.cpp)
add_executable(Hello ${SOURCE_FILES})
target_compile_features(Hello PRIVATE cxx_auto_type)

---

_{* я не пробовал это на CMake 3.1, но проверил, что он работает в CMake 3.3. Элемент документация 3.1 документирует это, поэтому он должен работать.}

мы написали модуль CMake для обнаружения и включения поддержки C++11, который вы можете найти здесь:
https://github.com/NitroShare/CXX11-CMake-Macros

Это все еще незавершенная работа, но мы используем ее для ряда проектов Qt, которые нацелены на Windows/Linux/Mac. В настоящее время поддерживаются только MSVC++, GCC и Clang.

пример:

include(CXX11)

check_for_cxx11_compiler(CXX11_COMPILER)

# If a C++11 compiler is available, then set the appropriate flags
if(CXX11_COMPILER)
    enable_cxx11()
endif()