Как мне получить несколько столбцов для использования в цикле курсора?

когда я пытаюсь запустить следующий фрагмент SQL внутри цикла курсора,

set @cmd = N'exec sp_rename ' + @test + N',' +
           RIGHT(@test,LEN(@test)-3) + '_Pct' + N',''COLUMN'''

Я получаю следующее сообщение

Msg 15248, Уровень 11, состояние 1, процедура sp_rename, строка 213
Либо параметр @objname неоднозначно или заявленное @objtype (столбец) неверно.

что не так и как это исправить ? Я попытался обернуть имя столбца в скобки [], и двойные кавычки "" как некоторые из поиска предполагаемые результаты.

изменить 1 -

вот весь сценарий. Как передать имя таблицы для переименования sp ? Я не уверен, как это сделать, так как имена столбцов находятся в одной из многих таблиц.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
declare @cmd nvarchar(500) 
declare Tests cursor for
SELECT COLUMN_NAME FROM INFORMATION_SCHEMA.COLUMNS WHERE COLUMN_NAME LIKE 'pct%' AND TABLE_NAME LIKE 'TestData%'

open Tests
fetch next from Tests into @test
while @@fetch_status = 0
BEGIN
  set @cmd = N'exec sp_rename ' + @test + N',' + RIGHT(@test,LEN(@test)-3) + '_Pct' + N', column' 

  print @cmd

  EXEC sp_executeSQL @cmd

  fetch next from Tests into @test
END

close Tests 
deallocate Tests


ROLLBACK TRANSACTION
--COMMIT TRANSACTION

редактировать 2 - Скрипт предназначен для переименования столбцов, имена которых соответствуют шаблону, в данном случае с "РСТ" префикс. Столбцы встречаются в различных таблицах базы данных. Все имена таблиц имеют префикс "TestData".

1 67
tsql sql-server-2005

1 ответ:

вот немного измененная версия. Изменения отмечаются в качестве комментария к коду.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
-- variable to hold table name
declare @tableName nvarchar(255)
declare @cmd nvarchar(500) 
-- local means the cursor name is private to this code
-- fast_forward enables some speed optimizations
declare Tests cursor local fast_forward for
 SELECT COLUMN_NAME, TABLE_NAME
   FROM INFORMATION_SCHEMA.COLUMNS 
  WHERE COLUMN_NAME LIKE 'pct%' 
    AND TABLE_NAME LIKE 'TestData%'

open Tests
-- Instead of fetching twice, I rather set up no-exit loop
while 1 = 1
BEGIN
  -- And then fetch
  fetch next from Tests into @test, @tableName
  -- And then, if no row is fetched, exit the loop
  if @@fetch_status <> 0
  begin
     break
  end
  -- Quotename is needed if you ever use special characters
  -- in table/column names. Spaces, reserved words etc.
  -- Other changes add apostrophes at right places.
  set @cmd = N'exec sp_rename ''' 
           + quotename(@tableName) 
           + '.' 
           + quotename(@test) 
           + N''',''' 
           + RIGHT(@test,LEN(@test)-3) 
           + '_Pct''' 
           + N', ''column''' 

  print @cmd

  EXEC sp_executeSQL @cmd
END

close Tests 
deallocate Tests

ROLLBACK TRANSACTION
--COMMIT TRANSACTION
118