Формат Infix для макроса Nemerle

Скажем, Мне нужен какой-то очень специальный оператор умножения. Он может быть реализован в следующем макросе: 

macro @<<!(op1, op2)
{
    <[ ( $op1 * $op2 ) ]>
}

И я могу использовать его как 

def val = 2 <<! 3

И его работа.

Но что мне действительно нужно, так это какой-нибудь "английский" оператор для DSL Im, развивающийся сейчас: 

macro @multiply(op1, op2)
{
    <[ ( $op1 * $op2 ) ]>
}

И если я попытаюсь использовать его как 

def val = 2 multiply 3

Компилятор завершает работу с ошибкой 'expected ;'

В чем проблема? Как я могу реализовать этот макрос в формате infix?

2 3
metaprogramming nemerle dsl

2 ответа:

Прямо из исходного кода компилятора: 

namespace Nemerle.English
{
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "and", false, 160, 161)]
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "or", false, 150, 151)]
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "not", true, 181, 180)]  

  macro @and (e1, e2) {
    <[ $e1 && $e2 ]>
  }

  macro @or (e1, e2) {
    <[ $e1 || $e2 ]>
  }

  macro @not (e) {
    <[ ! $e ]>
  }

Вам нужно посыпать OperatorAttributes вокруг, и это будет работать. Кстати, атрибут OperatorAttribute определяется следующим образом: 

public class OperatorAttribute : NemerleAttribute
{
  public mutable env : string;
  public mutable name : string;
  public mutable IsUnary : bool;
  public mutable left : int;
  public mutable right : int;
}
7

Как обычно, я нашел ответ раньше, чем ответило сообщество. :) Таким образом, решение состоит в том, чтобы просто использовать специальный атрибут assemply level, который определяет макрос как двоичный оператор: 

namespace TestMacroLib
{
  [assembly: Nemerle.Internal.OperatorAttribute ("TestMacroLib", "multiply", false, 160, 161)]
  public macro multiply(op1, op2)
  {
    <[ ( $op1 * $op2 ) ]>
  }
}
1