Delphi TObjectDictionary, имеющий ключ экземпляра класса [дубликат]

На этот вопрос уже есть ответ здесь:

У меня есть следующее class: 

TTest = class
private
  FId: Integer;
  FSecField: Integer;
  FThirdField: Integer;
public
  constructor Create(AId, ASecField, AThirdField: Integer);
  // ..... 
end;

Затем я создаю TObjectDictionary Вот так: 

procedure TMainForm.btnTestClick(Sender: TObject);
var
  TestDict: TObjectDictionary<TTest, string>;
  Instance: TTest;
begin
  TestDict := TObjectDictionary<TTest, string>.Create([doOwnsKeys]);

  try
    TestDict.Add(TTest.Create(1, 1, 1), '');

    if TestDict.ContainsKey(TTest.Create(1, 1, 1)) then
      ShowMessage('Match found')
    else
      ShowMessage('Match not found');

    Instance := TTest.Create(1, 1, 1);
    TestDict.Add(Instance, 'str');

    if TestDict.ContainsKey(Instance) then
      ShowMessage('Match found')
    else
      ShowMessage('Match not found');
  finally
    TestDict.Free;
  end;
end;
Результат: "совпадение не найдено", "совпадение найдено". Что я должен сделать, чтобы сравнить значения полей каждого ключа, но не их адреса?
1 4
generics delphi memory-address

1 ответ:

Компаратор равенства по умолчанию для переменной ссылки экземпляра сравнивает ссылку, а не объект. Таким образом, вы получаете идентичность объекта, а не идентичность ценности.

Поэтому вам нужно предоставить пользовательский компаратор равенства, если вы хотите ввести идентичность значений.

TestDict := TObjectDictionary<TTest, string>.Create(
  [doOwnsKeys], 
  TEqualityComparer<TTest>.Construct(EqualityComparison, Hasher)
);

Где EqualityComparison, Hasher есть функции сравнения и хэширования. Они могут быть реализованы следующим образом: 

EqualityComparison := 
  function(const Left, Right: TTest): Boolean
  begin
    Result := (Left.FId = Right.FId)
      and (Left.FSecField = Right.FSecField)
      and (Left.FThirdField = Right.FThirdField);
  end;

Hasher := 
  function(const Value: TTest): Integer
  begin
    Result := BobJenkinsHash(Value.FId, SizeOf(Value.FId), 0);
    Result := BobJenkinsHash(Value.FSecField, SizeOf(Value.FSecField), Result);
    Result := BobJenkinsHash(Value.FThirdField, SizeOf(Value.FThirdField), Result);
  end;
3